LayCase - layers maiusculos e minusculos

Aí esta a rotina que eu falei:

---

(defun c:laycase (/ dcl op x)
  (tbn:error-init nil)
  (setq dcl (load_dialog "laycase.dcl")
;opção padrão:
        op  (getcfg "Appdata/laycase/laycase")
        op  (if op op "maius"))
;carrega o dialogo:
  (new_dialog "laycase" dcl)
;configura as "action" do dialogo:
  (foreach x '("prma" "minus" "maius" "plsm" "invr")
    (action_tile x "(setq op $key)"))
;marca no dialogo a opção padrao:
  (set_tile op "1")
;inicia e espera o "OK":
  (if (= 1 (start_dialog))
    (progn
;altera os nomes dos layers:
      (vlax-for lay ;aplica em todos os layers
                (vla-get-layers ;pega a collection layers
                  (vla-get-activedocument; arquivo corrente
                    (vlax-get-acad-object)));autocad
        (vla-put-name lay (strcase2 (vla-get-name lay) op)))
;grava a opção escolhida:
      (setcfg "Appdata/laycase/laycase" op)))
  (unload_dialog dcl)
  (tbn:error-restore ))

---

agora o dcl:

---

laycase : dialog {label = "Maiúsculas / Minúsculas";
   :boxed_radio_column { label = "Escolha uma opção";
     :radio_button { label = "&Primeira letra da sentença em maiúsculas";
                     key = "prma";}
     :radio_button { label = "&minúsculas";
                     key = "minus";}
     :radio_button { label = "MAIÚS&CULAS";
                     key = "maius";}
     :radio_button { label = "Pr&imeira Letra De Cada Palavra Em Maiúsculas";
                     key = "plsm";}
     :radio_button { label = "i&NVERTER" ; key = "invr";}}
   :row {
     :text {label="Powered by Neyton®";}
     :button {label = "&Deixa pra lá..."; key="cancel"; is_cancel=true;}
     :button {label = "&Execute!"; key="accept"; is_default=true;}}}

---

Salve a rotina e o dcl numa pasta que o cad ache (support file)
Para usar, simplesmente digite LAYCASE na linha de comando e esolha uma opção